MatrixMultiply: kernel_single.il

mdef(0)_out(4)_in(6)
mad out0, in0.x, in1, in2
mad out1, in0.y, in1, in3
mad out2, in0.z, in1, in4
mad out3, in0.w, in1, in5
mend
il_ps_2_0
;
; 8x8 outer product version 
;   20100707 N.Nakasato (University of Aizu, Japan)
;   Provided "as is"
;
dcl_input_interp(linear) v0.xy
dcl_resource_id(0)_type(2d,unnorm)_fmtx(float)_fmty(float)_fmtz(float)_fmtw(float) ;A
dcl_resource_id(1)_type(2d,unnorm)_fmtx(float)_fmty(float)_fmtz(float)_fmtw(float) ;B
dcl_literal l0, 0.0, 1.0, 2.0, 3.0
dcl_literal l1, 4.0, 1.0, 2.0, 3.0
dcl_literal l2, -1.0, 1.0, -2.0, 3.0
dcl_literal l4, 1, 1, 1, 2
dcl_cb cb0[1]            ; {(float)n/4, (float)n, 0.0, 0.0} where n is matrix size 

flr r100.xy, v0.xy
mul r100.x, r100.x, l0.z ; x2
mul r100.y, r100.y, l0.z ; x2
mov r100.z, l2.z         ; -2

mov r50, l0.xxxx
mov r51, l0.xxxx
mov r52, l0.xxxx
mov r53, l0.xxxx
mov r54, l0.xxxx
mov r55, l0.xxxx
mov r56, l0.xxxx
mov r57, l0.xxxx

mov r60, l0.xxxx
mov r61, l0.xxxx
mov r62, l0.xxxx
mov r63, l0.xxxx
mov r64, l0.xxxx
mov r65, l0.xxxx
mov r66, l0.xxxx
mov r67, l0.xxxx

whileloop
  add r100.z, r100.z, l0.z  ; +2
  eq r999, r100.z, cb0[0].y
  break_logicalnz r999.x

  ; read A (transposed)
  sample_resource(0)_sampler(0)_aoffimmi(0.0,0.0,0.0) r30, r100.yz
  sample_resource(0)_sampler(1)_aoffimmi(1.0,0.0,0.0) r31, r100.yz

  ; read B
  sample_resource(1)_sampler(2)_aoffimmi(0.0,0.0,0.0) r32, r100.xz
  sample_resource(1)_sampler(3)_aoffimmi(1.0,0.0,0.0) r33, r100.xz

  mcall(0)(r50,r51,r52,r53),(r30,r32,r50,r51,r52,r53)
  mcall(0)(r60,r61,r62,r63),(r30,r33,r60,r61,r62,r63)

  mcall(0)(r54,r55,r56,r57),(r31,r32,r54,r55,r56,r57)
  mcall(0)(r64,r65,r66,r67),(r31,r33,r64,r65,r66,r67)

  ; read A (transposed)
  sample_resource(0)_sampler(4)_aoffimmi(0.0,1.0,0.0) r30, r100.yz
  sample_resource(0)_sampler(5)_aoffimmi(1.0,1.0,0.0) r31, r100.yz

  ; read B
  sample_resource(1)_sampler(6)_aoffimmi(0.0,1.0,0.0) r32, r100.xz
  sample_resource(1)_sampler(7)_aoffimmi(1.0,1.0,0.0) r33, r100.xz

  breakc_relop(eq) cb[0].z, l0.y
  mcall(0)(r50,r51,r52,r53),(r30,r32,r50,r51,r52,r53)
  mcall(0)(r60,r61,r62,r63),(r30,r33,r60,r61,r62,r63)

  mcall(0)(r54,r55,r56,r57),(r31,r32,r54,r55,r56,r57)
  mcall(0)(r64,r65,r66,r67),(r31,r33,r64,r65,r66,r67)
endloop

mul r100.y, r100.y, l1.x ; x2 x4 = x8
mov r1, r100.xy
mul r2.x, r1.y, cb0[0].x
add r2.x, r2.x, r1.x
ftoi r3.x, r2.x
ftoi r4.x, cb0[0].x

iadd r3.y, r3.x, l4.x
iadd r3.__zw, r3.xyxy, r4.xxxx

mov g[r3.x], r50
mov g[r3.y], r60
mov g[r3.z], r51
mov g[r3.w], r61

imul r4.x, r4.x, l4.w
iadd r3.xyzw, r3.xyzw, r4.xxxx
mov g[r3.x], r52
mov g[r3.y], r62
mov g[r3.z], r53
mov g[r3.w], r63

iadd r3.xyzw, r3.xyzw, r4.xxxx
mov g[r3.x], r54
mov g[r3.y], r64
mov g[r3.z], r55
mov g[r3.w], r65

iadd r3.xyzw, r3.xyzw, r4.xxxx
mov g[r3.x], r56
mov g[r3.y], r66
mov g[r3.z], r57
mov g[r3.w], r67

ret_dyn
endmain

end